1

In my .zshrc file I have written a function based on git log:

lg() {
    git log \
    --abbrev=12 \
    --graph \
    --oneline \
    --color=always \
    --format="%C(cyan)%h %C(blue)%ar %C(auto)%d %C(yellow)%s %C(white)%ae" "$@" |
    fzf

To enable autocompletion for this function I have added to my .zshrc:

compdef _git-log lg

The _git-log function is indeed the basic completion function for git log in zsh.

It is inside /usr/share/zsh/functions/Completion/Unix/_git.

But using this method as recommended here, doesn't work on my side.

After sourcing my .zshrc and try to use my lg command I keep getting in my terminal:

>$ lg (eval):1: command not found: _git-log

How to use completion functions from completions file for other function?

Edit: As suggested by @Stéphane Chazelas, I used the load_helper_functions from @Gille's answer.

At the end of my .zshrc, I have now :

load_helper_functions () {
    emulate -LR zsh
    if ((!$+functions[$1])) || [[ $functions[$1] = 'builtin autoload'* ]]; then
        autoload +X +U $1
        functions[$1]=${functions[$1]%$'\n'*}
        $1
  fi
}
load_helper_functions _git
compdef _git lg=git-log
Improve this question
1
  • Which method did you try? Please post enough code to reproduce the problem. Commented Sep 4, 2024 at 20:47

1 Answer 1

Reset to default
0

The _git-log function is only loaded upon first invocation of the _git autoloadable function and is not autoloadable on its own, so you'd need to either run _git once, or make _git-log somewhat autoloadable by pre-defining it as:

(( $+functions[_git-log] )) ||
  _git-log() { unfunction $0; service='not a function' _git; $0 "$@"; }

For it to load itself (along with the rest of the git completion framework) upon first invocation if not already loaded.

Note the service='not a function' as _git will try to run _$service if $service is a function which we don't won't it to here.

As an alternative to running the _git autoloadable function, you can use the load_helper_functions function from @Gilles' answer to Can I use a helper function from a ZSH completion file in another which interprets the code in the _git autoloadable function minus the last line which runs _git again after it has been redefined, which should work for most completion functions that use the same pattern to load helper functions.

Another approach which seems to work in my limited tests would be to do:

_lg() { words[1]=(git log); (( CURRENT++ )); _git "$@"; }
compdef _lg lg=git
Improve this answer
4
  • I use load_helper_functions from unix.stackexchange.com/questions/403820/… . (I don't remember if this evolved from code by you.) Commented Sep 5, 2024 at 22:12
  • Thanks @Gilles'SO-stopbeingevil', I've added a reference to your answer (and no, I don't think I was involved in that). Commented Sep 6, 2024 at 6:48
  • (And by the way, I think something is missing in this question, because it links to an answer that suggests _git 2>dev/null which isn't clean but works.) Commented Sep 6, 2024 at 7:46
  • @Gilles'SO-stopbeingevil' it's possible they missed that warning in your answer there (as I did when skimming over it). My answer does also suggests running _git but with service='not a function' to avoid running a potentially existing _$service function. Commented Sep 6, 2024 at 8:09

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.