Add test targets to the CMake build

Extend the CMake build system added in D91269570 to also build / run
tests. I mainly went for one listfile per subdirectory but lumped in
smaller disparate tests under mcrouter/lib into a single target for
simplicity. I omitted tests under mcrouter/lib/carbon/ as their
utility for OSS mcrouter is limited compared to the scaffolding needed
to run them (they interdepend on utilities from mcrouter/lib/network/test).

No changes to existing test files beyond the minimum needed to fix
compilation, so there are many expected failures in an OSS run.

Tested using a fresh copy of fbcode_builder.

Author: mszabo-wikia

.gitignore

@@ -0,0 +1 @@
+common/

CMake/carbon_thrift_types.py.in

@@ -0,0 +1,6 @@
+# Mock file for generated Carbon Python thrift types.
+# Used in OSS tests.
+from enum import Enum
+
+class Result(Enum):
+    OK = 1

CMake/fb303.thrift.in

@@ -0,0 +1 @@
+service FacebookService {}

CMake/mcrouter_config.py.in

@@ -0,0 +1,40 @@
+#!/usr/bin/env python3
+# Copyright (c) Meta Platforms, Inc. and affiliates.
+#
+# This source code is licensed under the MIT license found in the
+# LICENSE file in the root directory of this source tree.
+
+
+# Dummy Thrift client
+class ThriftTestClient:
+    def __init__(self, addr, port) -> None:
+        raise NotImplementedError
+
+    def sendVersion(self) -> str:
+        raise NotImplementedError
+
+
+class McrouterGlobals:
+    @staticmethod
+    def binPath(name):
+        bins = {
+            "mcrouter": "@CMAKE_BINARY_DIR@/bin/mcrouter",
+            "mcpiper": "@CMAKE_BINARY_DIR@/bin/mcpiper",
+            "mockmc": "@CMAKE_BINARY_DIR@/mcrouter/lib/network/test/mock_mc_server",
+            "mockmcthrift": "@CMAKE_BINARY_DIR@/mcrouter/lib/network/test/mock_mc_thrift_server",
+            "mockmcdual": "@CMAKE_BINARY_DIR@/mcrouter/lib/network/test/mock_mc_server_dual",
+            "prodmc": "@CMAKE_BINARY_DIR@/mcrouter/lib/network/test/mock_mc_server",
+        }
+        return bins[name]
+
+    @staticmethod
+    def preprocessArgs(args):
+        return args
+
+    @staticmethod
+    def useThriftClient():
+        return False
+
+    @staticmethod
+    def createThriftTestClient(addr, port) -> ThriftTestClient:
+        raise NotImplementedError

CMakeLists.txt

@@ -245,14 +245,84 @@ add_fbthrift_cpp_library(
   OPTIONS stack_arguments sync_methods_return_try deprecated_terse_writes
 )
 
-# Add source include directories to thrift targets
-# Generated thrift code includes headers like <mcrouter/lib/carbon/Keys.h>
-foreach(thrift_target
-    mcrouter_carbon_result_thrift
+set(THRIFT_TARGETS mcrouter_carbon_result_thrift
     mcrouter_carbon_thrift
     mcrouter_common_thrift
     mcrouter_memcache_thrift
     mcrouter_memcache_service_thrift)
+
+# Build test-only Thrift libraries.
+if(BUILD_TESTS)
+  # HelloGoodbyeService depends on fb303.FacebookService which isn't OSS,
+  # so supply a mock implementation.
+  # This sadly must be copied under the source directory rather than the build directory,
+  # because add_fbthrift_cpp_library() expects Thrift source file paths
+  # to be relative to the source directory root.
+  configure_file(
+    "${CMAKE_CURRENT_SOURCE_DIR}/CMake/fb303.thrift.in"
+    "${CMAKE_CURRENT_SOURCE_DIR}/common/fb303/if/fb303.thrift"
+    @ONLY
+  )
+
+  add_fbthrift_cpp_library(
+    fb303_facebookservice_mock
+    common/fb303/if/fb303.thrift
+  )
+
+  add_fbthrift_cpp_library(
+    mcrouter_hello_goodbye_thrift
+    mcrouter/lib/carbon/example/gen/HelloGoodbye.thrift
+    DEPENDS
+    mcrouter_carbon_thrift
+    mcrouter_carbon_result_thrift
+    mcrouter_common_thrift
+  )
+
+  add_fbthrift_cpp_library(
+    mcrouter_hello_goodbye_service_thrift
+    mcrouter/lib/carbon/example/gen/HelloGoodbyeService.thrift
+    DEPENDS
+    fb303_facebookservice_mock
+    mcrouter_hello_goodbye_thrift
+    SERVICES
+    HelloGoodbye
+    OPTIONS stack_arguments sync_methods_return_try
+  )
+
+  add_library(
+    mcrouter_hello_goodbye
+    mcrouter/lib/carbon/example/gen/HelloGoodbyeRouterInfo.cpp
+    mcrouter/lib/carbon/example/gen/HelloGoodbyeRouterInfo-BuildExtraProvider.cpp
+    mcrouter/lib/carbon/example/gen/HelloGoodbyeRouterInfo-ExternTemplate.cpp
+    mcrouter/lib/carbon/example/gen/HelloGoodbyeMessages.cpp
+    mcrouter/lib/carbon/example/gen/HelloGoodbyeMessagesThrift.cpp
+  )
+
+  target_link_libraries(
+    mcrouter_hello_goodbye
+    PUBLIC
+    mcrouter_hello_goodbye_service_thrift
+  )
+
+
+  add_fbthrift_cpp_library(
+    mcrouter_carbon_test_thrift
+    mcrouter/lib/network/test/gen/CarbonTest.thrift
+    DEPENDS
+    mcrouter_carbon_thrift
+    mcrouter_carbon_result_thrift
+  )
+
+  list(APPEND THRIFT_TARGETS
+    mcrouter_hello_goodbye_thrift
+    mcrouter_hello_goodbye_thrift
+    mcrouter_carbon_test_thrift
+  )
+endif()
+
+# Add source include directories to thrift targets
+# Generated thrift code includes headers like <mcrouter/lib/carbon/Keys.h>
+foreach(thrift_target ${THRIFT_TARGETS})
   target_include_directories(${thrift_target}
     PUBLIC
       $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
@@ -270,7 +340,9 @@ set(MCROUTER_LIB_SOURCES
   mcrouter/lib/Clocks.cpp
   mcrouter/lib/Compression.cpp
   mcrouter/lib/CompressionCodecManager.cpp
+  mcrouter/lib/DynamicUtil.cpp
   mcrouter/lib/FailoverErrorsSettingsBase.cpp
+  mcrouter/lib/FiberLocalInternal.cpp
   mcrouter/lib/IOBufUtil.cpp
   mcrouter/lib/IovecCursor.cpp
   mcrouter/lib/Lz4CompressionCodec.cpp
@@ -293,6 +365,7 @@ set(MCROUTER_LIB_SOURCES
   mcrouter/lib/carbon/ReplyCommon.cpp
   mcrouter/lib/carbon/RequestCommon.cpp
   mcrouter/lib/carbon/Result.cpp
+  mcrouter/lib/carbon/connection/ExternalCarbonConnectionImpl.cpp
 
   # Config
   mcrouter/lib/config/ConfigPreprocessor.cpp
@@ -353,6 +426,12 @@ set(MCROUTER_LIB_SOURCES
   mcrouter/lib/network/gen/CommonMessagesThrift.cpp
   mcrouter/lib/network/gen/MemcacheMessages.cpp
   mcrouter/lib/network/gen/MemcacheMessagesThrift.cpp
+  mcrouter/lib/network/gen/MemcacheRouterInfo.cpp
+  mcrouter/lib/network/gen/MemcacheRouterInfo-AllFastestRoute.cpp
+  mcrouter/lib/network/gen/MemcacheRouterInfo-BuildExtraProvider.cpp
+  mcrouter/lib/network/gen/MemcacheRouterInfo-ExternTemplate.cpp
+  mcrouter/lib/network/gen/MemcacheRouterInfo-FailoverRoute.cpp
+  mcrouter/lib/network/gen/MemcacheRouterInfo-HashRoute.cpp
 )
 
 add_library(mcrouter_lib ${MCROUTER_LIB_SOURCES})
@@ -566,8 +645,10 @@ install(
 if(BUILD_TESTS)
   enable_testing()
   find_package(GTest CONFIG REQUIRED)
+  include(GoogleTest)
 
-  # Add test subdirectories when ready
-  # add_subdirectory(mcrouter/lib/test)
-  # add_subdirectory(mcrouter/test)
+  add_subdirectory(mcrouter/lib/test)
+  add_subdirectory(mcrouter/lib/network/test)
+  add_subdirectory(mcrouter/routes/test)
+  add_subdirectory(mcrouter/test)
 endif()

mcrouter/lib/network/test/CMakeLists.txt

@@ -0,0 +1,63 @@
+add_library(
+  mcrouter_network_test_util
+  STATIC
+  ClientSocket.cpp
+  ListenSocket.cpp
+  MockMc.cpp
+  SessionTestHarness.cpp
+  TestClientServerUtil.cpp
+  TestMcAsciiParserUtil.cpp
+  gen/CarbonTestMessages.cpp
+  gen/CarbonTestMessagesThrift.cpp
+)
+
+target_link_libraries(
+  mcrouter_network_test_util
+  PUBLIC
+    mcrouter_lib
+    mcrouter_carbon_test_thrift
+    GTest::gtest
+)
+
+# =============================================================================
+# Mock server executables (used for integration tests)
+# =============================================================================
+add_executable(mock_mc_server MockMcServer.cpp MockMc.cpp)
+target_link_libraries(mock_mc_server PRIVATE mcrouter_lib)
+
+add_executable(mock_mc_thrift_server MockMcThriftServer.cpp MockMc.cpp)
+target_link_libraries(mock_mc_thrift_server PRIVATE mcrouter_lib)
+
+add_executable(mock_mc_server_dual MockMcServerDual.cpp MockMc.cpp)
+target_link_libraries(mock_mc_server_dual PRIVATE mcroutercore)
+
+add_executable(
+  mcrouter_network_test
+  ${CMAKE_SOURCE_DIR}/mcrouter/lib/test/Main.cpp
+  AccessPointTest.cpp
+  AsyncMcClientTestSync.cpp
+  AsyncMcServerShutdownTest.cpp
+  AsyncMcServerTest.cpp
+  CarbonMessageDispatcherTest.cpp
+  CarbonMockMcTest.cpp
+  CarbonQueueAppenderTest.cpp
+  McAsciiParserTest.cpp
+  McParserTest.cpp
+  McServerAsciiParserTest.cpp
+  MemcacheConnectionTest.cpp
+  MemcacheTest.cpp
+  RequestExpiryTest.cpp
+  SessionTest.cpp
+)
+
+target_link_libraries(
+  mcrouter_network_test
+  PRIVATE
+    mcrouter_network_test_util
+    mcroutercore
+    mcrouter_hello_goodbye
+    GTest::gtest
+    GTest::gmock
+)
+
+gtest_discover_tests(mcrouter_network_test WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})

mcrouter/lib/test/CMakeLists.txt

@@ -0,0 +1,36 @@
+include(GoogleTest)
+
+add_executable(
+  mcrouter_lib_test
+  Main.cpp
+  CompressionTestUtil.cpp
+  HashTestUtil.cpp
+  Ch3HashTest.cpp
+  CompressionTest.cpp
+  CompressionCodecManagerTest.cpp
+  Crc32HashTest.cpp
+  DynamicUtilTest.cpp
+  FiberLocalTest.cpp
+  IovecCursorTest.cpp
+  Lz4ImmutableTest.cpp
+  McResUtilTest.cpp
+  MigrateRouteTest.cpp
+  RandomRouteTest.cpp
+  RendezvousHashTest.cpp
+  RouteHandleTest.cpp
+  WeightedCh3HashFuncTest.cpp
+  WeightedChHashFuncBaseTest.cpp
+  WeightedRendezvousHashTest.cpp
+  observable_test.cpp
+  runtime_vars_data_test.cpp
+)
+
+target_link_libraries(
+  mcrouter_lib_test
+  PRIVATE
+    mcrouter_lib
+    GTest::gtest
+    GTest::gmock
+)
+
+gtest_discover_tests(mcrouter_lib_test)

mcrouter/routes/test/CMakeLists.txt

@@ -0,0 +1,50 @@
+add_executable(
+  mcrouter_routes_test
+  Main.cpp
+  BigValueRouteTest.cpp
+  BlackholeRouteTest.cpp
+  ClientCompatibilityCheckerRouteTest.cpp
+  CollectionRouteFactoryTest.cpp
+  ConstShardHashFuncTest.cpp
+  DistributionRouteTest.cpp
+  EagerShardSelectionRouteTest.cpp
+  EagerShardSelectionShadowRouteTest.cpp
+  ErrorRouteTest.cpp
+  FailoverRouteTest.cpp
+  FailoverWithExptimeRouteTest.cpp
+  HashStopAllowListRouteTest.cpp
+  KeyParseRouteTest.cpp
+  KeySplitRouteTest.cpp
+  LatencyInjectionRouteTest.cpp
+  LatestRouteTest.cpp
+  LoadBalancerRouteTest.cpp
+  LoggingRouteTest.cpp
+  McBucketRouteTest.cpp
+  MissFailoverRouteTest.cpp
+  OriginalClientHashRouteTest.cpp
+  OutstandingLimitRouteTest.cpp
+  PrefixSelectorRouteTest.cpp
+  RateLimitRouteTest.cpp
+  RootRouteTest.cpp
+  RoutePolicyMapTest.cpp
+  ShadowRouteTest.cpp
+  ShadowSettingsTest.cpp
+  ShardSelectionRouteTest.cpp
+  ShardSplitRouteTest.cpp
+  ShardSplitterTest.cpp
+  SlowWarmUpRouteTest.cpp
+  StagingRouteTest.cpp
+  WarmUpRouteTest.cpp
+)
+
+target_link_libraries(
+  mcrouter_routes_test
+  PRIVATE
+    mcrouter_hello_goodbye
+    mcroutercore
+    Folly::follybenchmark
+    GTest::gtest
+    GTest::gmock
+)
+
+gtest_discover_tests(mcrouter_routes_test)

mcrouter/routes/test/ShadowSettingsTest.cpp

@@ -10,9 +10,13 @@
 #include <folly/Range.h>
 #include <folly/json/json.h>
 
+#ifndef MCROUTER_OSS_BUILD
 #include "configerator/distribution/api/ScopedConfigeratorFake.h"
+#endif
 #include "mcrouter/CarbonRouterInstance.h"
+#ifndef MCROUTER_OSS_BUILD
 #include "mcrouter/facebook/FbConfigApi.h"
+#endif
 #include "mcrouter/lib/network/gen/MemcacheRouterInfo.h"
 #include "mcrouter/routes/ShadowSettings.h"
 
@@ -184,6 +188,7 @@ TEST_F(ShadowSettingsTest, shouldRouteByBucket) {
   }
 }
 
+#ifndef MCROUTER_OSS_BUILD
 TEST_F(ShadowSettingsTest, keyFractionRangeRV) {
   // configure RuntimeVarsFile
   facebook::configerator::ScopedConfigeratorFake configeratorFake;
@@ -222,3 +227,4 @@ TEST_F(ShadowSettingsTest, keyFractionRangeRV) {
   uint32_t expectedKeyFraction = 0.1 * std::numeric_limits<uint32_t>::max();
   ASSERT_TRUE(keyFraction == expectedKeyFraction);
 }
+#endif