I have a list:
list={{{1},{2},{1,2},{1,2,3},{},{}},{{2},{3},{}}}
I would like to remove the empty lists {} to get:
{{{1},{2},{1,2},{1,2,3}},{{2},{3}}}
How can I automate this using Mathematica ?
$\begingroup$
$\endgroup$
2
-
2$\begingroup$ Strongly related: mathematica.stackexchange.com/q/261187/1871 $\endgroup$xzczd– xzczd ♦2023-12-27 02:48:08 +00:00Commented Dec 27, 2023 at 2:48
-
$\begingroup$ also strongly related $\endgroup$user1066– user10662023-12-29 23:05:10 +00:00Commented Dec 29, 2023 at 23:05
Add a comment
|
5 Answers
$\begingroup$
$\endgroup$
Using ReplaceAll (which can also be written /.) we can replace all the empty lists { } with Nothing.
list /. {} -> Nothing
{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}
$\begingroup$
$\endgroup$
3
Using DeleteCases:
list1 = {{{1}, {2}, {1, 2}, {1, 2, 3}, {}, {}}, {{2}, {3}, {}}};
DeleteCases[list1, {}, 2]
(*{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}*)
Considering the @Nasser's observation, we can generalize this strategy introducing the depth of the array to apply it in more complicated cases, as I show below:
DeleteCases[#, {}, Depth@#] &@list1
(*{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}*)
list2 = {{{1}, {2}, {1, 2}, {1, 2, 3}, {}, {}}, {3, {{{2}, {3}, {}}}}};
DeleteCases[#, {}, Depth@#] &@list2
(*{{{1}, {2}, {1, 2}, {1, 2, 3}}, {3, {{{2}, {3}}}}}*)
Thanks to Nasser for this valuable observation.
Another way, as suggested by @AndreasLauschke is to put Infinity instead of 2:
DeleteCases[list1, {}, ∞]
(*{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}*)
-
2$\begingroup$ fyi, this does not work on general. It works for the input given. For example, if the input was
list={{{1},{2},{1,2},{1,2,3},{},{}},{3,{{{2},{3},{}}}}};thenDeleteCases[list,{},2]does not remove the{}. Screen shot !Mathematica graphics $\endgroup$Nasser– Nasser2023-12-26 23:37:59 +00:00Commented Dec 26, 2023 at 23:37 -
2$\begingroup$ Use Infinity instead of 2 $\endgroup$Andreas Lauschke– Andreas Lauschke2023-12-26 23:46:04 +00:00Commented Dec 26, 2023 at 23:46
-
$\begingroup$ @AndreasLauschke You're right, thanks for the suggestion. :-) $\endgroup$E. Chan-López– E. Chan-López2023-12-26 23:49:27 +00:00Commented Dec 26, 2023 at 23:49
$\begingroup$
$\endgroup$
list = {{{1}, {2}, {1, 2}, {1, 2, 3}, {}, {}}, {{2}, {3}, {}}};
p = Position[{}] @ list;
{{1, 5}, {1, 6}, {2, 3}}
Delete[p] @ list
{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}
MapAt[Nothing, p] @ list
{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}
ReplacePart[p -> Nothing] @ list
{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}
ReplaceAt[_ :> Nothing, p] @ list
{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}
$\begingroup$
$\endgroup$
2
list //. {} -> Sequence[]
and
list //. {} :> Unevaluated[## &[]]
both give
{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}
-
1$\begingroup$ (+1) I hadn't seen the second one, nicely done mate! :-) $\endgroup$E. Chan-López– E. Chan-López2023-12-27 04:04:19 +00:00Commented Dec 27, 2023 at 4:04
-
1$\begingroup$ @E.Chan-López thanks a lot! :-) $\endgroup$bmf– bmf2023-12-27 05:09:54 +00:00Commented Dec 27, 2023 at 5:09
$\begingroup$
$\endgroup$
list = {{{1}, {2}, {1, 2}, {1, 2, 3}, {}, {}}, {{2}, {3}, {}}}
Using SequenceCases
SequenceCases[#, {a_, {} ...} :> a] & /@ list
{{{1}, {2}, {1, 2}, {1, 2, 3}}, {{2}, {3}}}