Modify numeric values with Perl one-liner

The following discussion was posted as comments but they ended up running too long for comments and I guess they do constitute an answer so here it is, expanded.

The problem is not Perl's string-vs-number treatment but the fact that the whole replacement side in s/// is processed as a double-quoted string, yielding a direct replacement for what is matched. The dollar variables, if populated in captures, do get interpolated. So you get the value for $1, followed by the sequence of characters + and 1, and then follow the , and the space and the value for $2 followed by characters + and 1.

One cannot do anything there while you'd like to add as + is meant as an operation. With the /e modifier^† the replacement side is evaluated as code and then you can write Perl code in there, so that $1 + 1 is an addition -- but then the whole replacement side is one piece of code, the result of which is used to replace everything matched. Thus the need to use concatenation . in code, to handle (reproduce) the comma and spaces that were matched, etc. We still must capture on the matching side whatever is meant to be available in a dollar variable.

So apart from needing to add $1 and 1 you also need to then tack a comma and a space onto it, and then concatenate the other piece, $2 + 1, so

s/^([0-9]+), ([0-9]+)/($1+1) . ", " . ($2+1)/e

Thus the answer by 0stone0

On the other hand, Perl very readily converts between strings and numbers as needed; one could say that it is even too eager. So if you say on the command line

perl -wE'my $v = "a"; say $v + 1'   # warns, converts 'a' to 0, adds

it will treat $v as a number because of that +, and will warn that it isn't numeric (if you enable warnings, what you should) -- and it will do it: 'a' gets converted to 0 and it adds 1 to it.

The capital E there is e with "features" enabled so we can use say. One may avoid to use it in one-liners that are meant for long-term use because things change in the language and with E everything is enabled so one may be using a feature one never even heard of but which at some point ends up affecting the code.

^† Search for the word modifier in perlretut: Simple word matching, for example. The full, more strict, reference is perlre.

Your data is well strcutured, so i don't see any benefit from using Regex here.

You can just parse the file, parse the lines, get first two items from each line, add 1 to them and write back.

In my opinion, here regex will be too implicit. I always prefer explicit implementation, if implicit option does not give me great benefits.

Here's simple example:

#!/usr/bin/env perl
use strict;
use warnings;

my $data = <<'END_DATA';
0, 0, (1.263566e+02, -5.062154e+02)
0, 1, (1.069488e+02, -1.636887e+02)
0, 2, (-2.281294e-01, -7.787449e-01)
0, 3, (5.492424e+00, -4.145492e+01)
0, 4, (-7.961223e-01, 2.740912e+01)
END_DATA

for my $line (split /\n/, $data) {
    my @fields = split /, /, $line, 3;   # i, j, "(real, imag)"
    $fields[0]++;
    $fields[1]++;
    print join(", ", @fields), "\n";
}

Given the nice structure of your file (CSV) and its simplicity (only contains numbers which use . as decimal separator), I think that it would be easier to use autosplit (-a) rather than a regex:

perl -F, -ane '$F[0]++; $F[1]++; print join ",", @F'

(the -F, flag tells Perl to split on commas instead of spaces)