Censor text with regex

You can do it with sed too:

sed '/^[[:blank:]]*-[[:blank:]]/{
h
s///
s/./X/g
x
s/\([[:blank:]]*-[[:blank:]]\).*/\1/
G
s/\n//
}' infile

This copies the line over the hold buffer, removes the first part [[:blank:]]*-[[:blank:]], replaces the remaining characters with an X, then exchanges pattern/hold space so now the censored string is in the hold pattern and the original line is back into the pattern space. The second part of the line is removed with s/\(...\).*//, the string in the hold space is appended to pattern space (G) and the \newline char is removed. So with a file like:

- line here
not - to be modified
  - a b c d e
 - another line-here

the output is:

- XXXXXXXXX
not - to be modified
  - XXXXXXXXX
 - XXXXXXXXXXXXXXXXX

If you want to remove blank chars and replace only the non-blank ones with X:

sed '/^[[:blank:]]*-[[:blank:]]/{
h
s///
s/[[:blank:]]//g
s/./X/g
x
s/\([[:blank:]]*-[[:blank:]]\).*/\1/
G
s/\n//
}' infile

output:

- XXXXXXXX
not - to be modified
  - XXXXX
 - XXXXXXXXXXXXXXXX

or, in one line with gnu sed:

sed -E '/^[ \t]*-[ \t]/{h;s///;s/[ \t]//g;s/./X/g;x;s/([ \t]*-[ \t]).*/\1/;G;s/\n//}' infile

Adjust the regex (i.e. ^[[:blank:]]*-[[:blank:]]) as per your needs.

$ awk '/^[ ]*- /{gsub(/[^ -]/,"X",$0)}1' <<EOM
- Hello
  - World 2015
This is not - censored
EOM

- XXXXX
  - XXXXX XXXX
This is not - censored

The awk expression looks for any lines that begins with a - character, after optional whitespaces. For matching lines, the gsub() command replaces all characters except for whitespaces and the - character. The final 1 is just a shortcut for {print $0}, i.e. to re-print the entire line.

edit: Since you also require removing/replacing the whitespace characters with X too, I can't really think of a more elegant solution other than to do an additional replacement:

$ awk '/^[ ]*- /{gsub(/[^ -]/,"X",$0);gsub(/X X/,"XXX",$0)}1' <<EOM
- Hello World
  - Earth
This is not - censored
EOM

- XXXXXXXXXXX
  - XXXXX
This is not - censored

To replace all alphanumeric characters with X:

$ tr '[:alnum:]' 'X' <file
- XXXXX XXXXX
  - XXXXX

To fill in the spaces between words:

$ tr '[:alnum:]' 'X' <file | sed 's/X X/XXX/g'
- XXXXXXXXXXX
  - XXXXX

Or, using only sed:

$ sed 's/[[:alnum:]]/X/g; s/X X/XXX/g' file
- XXXXXXXXXXX
  - XXXXX

Using sed as above, but also restrict the modification to lines that starts with a dash, preceded by optional spaces and/or tabs:

$ sed '/^[[:blank:]]*-/ { s/[[:alnum:]]/X/g; s/X X/XXX/g; }' file
- XXXXXXXXXXX
  - XXXXX

You may notice that the filling in of spaces only works when there are no single letter words in the data. A string like This is a tree would be converted into XXXXXXXXX XXXX. To avoid this, you may do a simple loop:

sed -e '/^[[:blank:]]*-/ { s/[[:alnum:]]/X/g; :again' \
    -e 's/X X/XXX/g; t again' -e '}' file

This performs the second substitution and then jump back to the again label if that substitution actually changed something.

Or, simpler, but would miss a trailing space character:

sed '/^[[:blank:]]*-/ { s/[[:alnum:]]/X/g; s/X /XX/g; }' file

if the spaces in the mentioned lines not important you could use the below line

Q='Some things\n - Hellow World\n   - Earth\nSome things Else'
echo -e "$Q" | awk '{ if ($0 ~ /^\s+-\s\w+/) print system("echo " $0 "| tr [:alnum:] x "); else print $0; }'  | grep -v ^0$

$0 ~ /^\s+-\s\w+/ check regex as you mentioned.

system(...) run Bash command inside awk

grep -v ^0$ this part because system(...) return exit code status.

we could get rid of grep -v ^0$ part with getline I/O statements but it is more complicated.