4
$\begingroup$

As a beginner with Mathematica, I apologize if this question is too basic. I would like to show introductory students that a complex number can be represented in several different coordinate systems on the complex plane — not only the usual Cartesian form

\begin{equation} z = x + i y \end{equation}

but also other coordinate systems such as polar and elliptic coordinates.

My goal is to make this demonstration more engaging, rather than simply writing the equations on the blackboard. I do not intend to go deeply into these coordinate systems, but rather to give students an intuitive visual sense that the complex plane is just $\mathbb{R}^2$, and that many different coordinate grids (specifically Cartesian, polar, and elliptic) can be used to locate the same point $z$.

$\textbf{Question:}$ Is there a clear and visual way to demonstrate these different representations of a complex number to students?

Any suggestions or examples would be greatly appreciated.

Improve this question
$\endgroup$
3
  • 3
    $\begingroup$ Well, again, personally I'd argue this question is not specific enough, but anyway, have you checked the Visual Complex Analysis by Tristan Needham? $\endgroup$ Commented 2 days ago
  • 2
    $\begingroup$ I’ve never seen elliptic coordinates used for complex numbers, and I don’t think your students need to deal with that. They only need to understand and visualize $x+iy$ and $r e^{i\theta}$. $\endgroup$ Commented 2 days ago
  • $\begingroup$ I would argue that it is natural to graphically represent complex numbers as points in the plane, but to avoid confusion I would definitely not suggest that such a plane is $\mathbb R^2$, since there are specific rules about how multiplication works in $\mathbb C$ that correspond to meaningful geometric interpretations. In fact, discussing complex multiplication is how I would motivate the polar coordinate system and representation. $\endgroup$ Commented yesterday

2 Answers 2

Reset to default
2
$\begingroup$

You could draw coordinates lines. Assume that the coordinates are named u and v. Then we can draw u-lines for fix u and variable v as well as v-lines vor fixed v and variable u. If we interpolate the lines, we can assign to every point of the RxR plane a crossing point of u and v lines.

Toward this aim, we may define the cartesian coordinates as functions of u and v. In addition we also declare a suitable range for u and v, adapted to the various coordinates.

cart = {u, v}; ccart = {{u, -1, 1}, {v, -1, 1}};
polar = {u Cos[v], u Sin[v]}; cpolar = {{u, 0, 2}, {v, 0, 2 Pi}};
ellip = {Cosh[u] Cos[v], 
  Sinh[u] Sin[v]}; cellip = {{u, 0, 2}, {v, 0, 2 Pi}};

With this we may draw a Manipulate that lets us display the different coordinate systems:

Manipulate[
 coord = Switch[co, "Cart", cart, "Polar", polar, "Ellip", ellip];
 range = Switch[co, "Cart", ccart, "Polar", cpolar, "Ellip", cellip];
 ParametricPlot[Evaluate@coord, Evaluate[Sequence @@ range], 
  Mesh -> 15, PlotRange -> {{-1, 1}, {-1, 1}}, PlotStyle -> None, 
  Frame -> False, Axes -> False]
 , {{co, "Cart", "Coordinates"}, {"Cart", "Polar", "Ellip"}}]

enter image description here

Improve this answer
$\endgroup$
2
$\begingroup$

The same spiral pl is depicted on the three coordinate systems.

A detail near the origin for elliptic coordinate system is added.

pl = ParametricPlot[fi {Cos[fi], Sin[fi]}, {fi, 0, 2 Pi}, 
   PlotRange -> 8, PlotRangePadding -> 0.025, Axes -> False, 
   PlotStyle -> ColorData[97, 3]];

s1 = Directive[AbsoluteThickness[1], ColorData[97, 2], Opacity[0.7]];
s2 = Directive[AbsoluteThickness[1], ColorData[97, 1], Opacity[0.7]];

Show[ParametricPlot[{u, v}, Sequence[{u, -8, 8}, {v, -8, 8}], 
  Mesh -> 15, MeshStyle -> {s1, s2}, 
  BoundaryStyle -> Directive[Black, Opacity[0.7]], PlotStyle -> None, 
  Frame -> False, Axes -> True, Ticks -> {Range[-8, 8], Range[-8, 8]},
   PlotRangePadding -> 2.5], pl]

Show[PolarPlot[fi, {fi, 0, 2 Pi}, 
  PolarGridLines -> {Append[{#}, s1] & /@ 
     Range[0, 2 Pi - Pi/12, Pi/12], Append[{#}, s2] & /@ Range[8]}, 
  PolarTicks -> {Automatic, Range[0, 8]}, PolarAxes -> True, 
  PlotRangePadding -> 2.5, PlotStyle -> None], pl]

ParametricPlot[
  Table[ReIm[1 Cosh[u + I v]], {u, {Range[0, 3, 0.5]}}], {v, 0, 2 Pi},
   PlotStyle -> s2, 
  Epilog -> {Table[
     Inset[Style[v, Small], ReIm[1 Cosh[3.1 + I v]]], {v, 0, 
      2 Pi - Pi/12, Pi/12}], 
    Table[Inset[
      Style[u, Small], {0.5, 0} + ReIm[1 Cosh[u + I Pi/2]]], {u, 0.5, 
      3, 0.5}]}, Axes -> False, PlotRange -> 8.5, 
  PlotRangePadding -> 3.5];
ParametricPlot[
  Table[ReIm[1 Cosh[u + I v]], {v, 0, 2 Pi, Pi/12}], {u, 0, 3}, 
  PlotStyle -> s1];
Show[%%, %, pl]

ParametricPlot[
  Table[ReIm[1 Cosh[u + I v]], {u, {Range[0, 1, 0.1]}}], {v, 0, 2 Pi},
   PlotStyle -> s2, 
  Epilog -> {Table[
     Inset[Style[v, Small], ReIm[1 Cosh[1.15 + I v]]], {v, 0, 
      2 Pi - Pi/12, Pi/12}], 
    Table[Inset[
      Style[u, Small], {0.1, 0} + ReIm[1 Cosh[u + I Pi/2]]], {u, 0, 1,
       0.2}]}, Axes -> False, 
  PlotRange -> {{-1.85, 1.85}, {-1.65, 1.65}}, PlotRangePadding -> 0];
ParametricPlot[
  Table[ReIm[1 Cosh[u + I v]], {v, 0, 2 Pi, Pi/12}], {u, 0, 1}, 
  PlotStyle -> s1];
Show[%%, %, pl]

enter image description here

enter image description here

Improve this answer
$\endgroup$

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.