Considering we have an array:
a = {2/3, 4/5, 9/7, 3/7, 1/7, 1/9};
How can I get this to be:
"2/3 4/5 9/7 3/7 1/7 1/9"
Thanks!
$\begingroup$
$\endgroup$
1
-
$\begingroup$ Related: (7063), (15032), (20412), (56419) $\endgroup$Mr.Wizard– Mr.Wizard2015-04-12 16:39:46 +00:00Commented Apr 12, 2015 at 16:39
Add a comment
|
5 Answers
$\begingroup$
$\endgroup$
I would love this to be uniform for both integer and rational numbers
a2 = {2/3, 4/5, 9/7, 3/7, 1.5, 3, 1/9};
StringTrim@StringJoin[" " <> ToString[#, InputForm] & /@ a2]
(* 2/3 4/5 9/7 3/7 1.5 3 1/9 *)
Row[ToString[#, InputForm] & /@ a2, " "]
(* 2/3 4/5 9/7 3/7 1.5 3 1/9 *)
StringReplace[ToString[a, InputForm], {"{" | "}" -> "", "," -> " "}]
(* 2/3 4/5 9/7 3/7 1.5 3 1/9 *)
StringJoin[Riffle[ToString[#, InputForm] & /@ a2, " "]]
(* 2/3 4/5 9/7 3/7 1.5 3 1/9 *)
$\begingroup$
$\endgroup$
4
Or
StringTake[ToString[a, FormatType -> InputForm], {2, -2}]
The inelegant use of StringTake strips off the leading and trailing brackets.
answered Apr 12, 2015 at 10:14
High Performance Mark
1,5341 gold badge10 silver badges17 bronze badges
-
$\begingroup$ Elegant! You can use
StringDelete[..., "{" | "}" | ","]instead ofStringTake. $\endgroup$István Zachar– István Zachar2015-04-12 10:29:30 +00:00Commented Apr 12, 2015 at 10:29 -
1$\begingroup$ Nice. Btw, this does not give the same form the OP wanted due the "," being there between the numbers. May be just need small modification? $\endgroup$Nasser– Nasser2015-04-12 10:51:48 +00:00Commented Apr 12, 2015 at 10:51
-
$\begingroup$ May be just need small modification? -- Surely, but left as an exercise for the reader :-) $\endgroup$High Performance Mark– High Performance Mark2015-04-12 11:46:27 +00:00Commented Apr 12, 2015 at 11:46
-
1$\begingroup$ Nice to see you here @HighPerformanceMark ! :-) $\endgroup$Mr.Wizard– Mr.Wizard2015-04-12 16:47:37 +00:00Commented Apr 12, 2015 at 16:47
$\begingroup$
$\endgroup$
Terse:
a = {1, 17, 2/3, 4/5, 9/7, 3/7, 1/7, 1/9};
ToString @ Row[InputForm /@ a, " "]
"1 17 2/3 4/5 9/7 3/7 1/7 1/9"
$\begingroup$
$\endgroup$
Yet another possibility:
a = {2/3, 4/5, 9/7, 3/7, 1/7, 1/9, 5, 6, 99/10};
ExportString[{a}, "Table", "FieldSeparators" -> " "]
"2/3 4/5 9/7 3/7 1/7 1/9 5 6 99/10"
answered Aug 11, 2017 at 7:41
J. M.'s missing motivation
127k11 gold badges411 silver badges591 bronze badges
$\begingroup$
$\endgroup$
1
a = {2/3, 4/5, 9/7, 3/7, 1/7, 1/9};
StringJoin@Cases[a, Rational[x_, y_] :>
" "<>ToString[x] <> "/" <> ToString[y]]
Reply to comment "I would love this to be uniform for both integer and rational numbers":
a = {2/3, 4/5, 9/7, 3/7, 1/7, 1/9, 5, 6, 99/10};
f[Rational[x_, y_]] := " " <> ToString[x] <> "/" <> ToString[y];
f[x_] := " " <> ToString[x];
StringJoin[f[#] & /@ a]
-
$\begingroup$ I would love this to be uniform for both integer and rational numbers. Thanks! $\endgroup$SuTron– SuTron2015-04-12 10:00:08 +00:00Commented Apr 12, 2015 at 10:00