1

I think this script should work to set keybinds, but it's currently quite borked--UPDATE: it has been unborked, and now works. It is ugly though, and I'm soliciting ways to make it more elegant, as I need to copy-paste four lines every time I want a new key bind.

I claim that since zsh doesn't support 2d arrays, I'm probably best off rewriting this in python.... updated, that python script lives here

A question of how to set keybindings correctly lives here.

#!/bin/zsh
# How many keybinds?
N=16
# Put keybindings here
k0=("keyboard dvorak nocaps" "Menu" "setxbmap dvorak -option nocaps")
k1=("launch code" "<Super>c" "code")
k2=("dropdown firefox" "<Shift><Super>f" "tdrop -ma -h \"100%\" -w \"50%\" firefox")

mkeys="org.gnome.settings-daemon.plugins.media-keys"
_locstr="/org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom"
_ck="$mkeys.custom-keybinding:$_locstr"
M="$(expr $N - 1)"

# Create spaces for $N keybindings, emulating the command:
# gsettings set org.gnome.settings-daemon.plugins.media-keys custom-keybindings "['/org/gnome/settings-daemon/plugins/ media-keys/custom-keybindings/custom0/', '/org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom1/ ']"
locations=""
for i in $(seq 0 $M); do
  locations+="'$_locstr$i/', "
done
locations+="'$_locstr$N/' "
gsettings set $mkeys custom-keybindings "[$locations]"


# issue commands. Have to paste 4 lines each time, kinda gross.
ck="${_ck}0/"
gsettings set $ck name    $k0[1]
gsettings set $ck binding $k0[2]
gsettings set $ck command $k0[3]
ck="${_ck}1/"
gsettings set $ck name    $k1[1]
gsettings set $ck binding $k1[2]
gsettings set $ck command $k1[3]
ck="${_ck}2/"
gsettings set $ck name    $k2[1]
gsettings set $ck binding $k2[2]
gsettings set $ck command $k2[3]

# test with:
# i=0
# ck="${_ck}$i/"
# gsettings get org.gnome.settings-daemon.plugins.media-keys custom-keybindings
# gsettings list-recursively $ck
Improve this question
11
  • Welcome, for i in {0..$M} won't work, the construct {n..n} doesn't allow parameters. You can use seq: for i in $(seq 1 $M). Commented May 29, 2022 at 22:21
  • that actually seems to be working fine, I did check it. Commented May 29, 2022 at 22:24
  • 1
    @schrodingerscatcuriosity, that's a limitation of bash and bash only, zsh (where {0..10} comes from actually) doesn't have that limitation. Commented May 30, 2022 at 7:50
  • 1
    @StéphaneChazelas OP's original question was about bash, it was edited later and changed to zsh. Commented May 30, 2022 at 8:34
  • 1
    I would stay away from os.system() that invokes a shell to parse shell code, so you're introducing all sorts of problems including potential code injection vulnerabilities. It would be like using eval in shells. See subprocess.run() / subprocess.call() instead in python. Commented May 31, 2022 at 6:29

1 Answer 1

Reset to default
2

Some avenues for improvement:

#! /bin/zsh -

bindings=(
  'keyboard dvorak nocaps' Menu              'setxbmap dvorak -option nocaps'
  'launch code'            '<Super>c'        code
  'dropdown firefox'       '<Shift><Super>f' 'tdrop -ma -h 100% -w 50% firefox'
)

mkeys=org.gnome.settings-daemon.plugins.media-keys
locstr=/${mkeys//./\/}/custom-keybindings/custom
ck=$mkeys.custom-keybinding:$locstr

locations=() i=0
for name binding command ($bindings) {
  for type (name binding command) gsettings set $ck$i $type ${(P)type}
  locations+=( "'$locstr$i'" )
  (( i++ ))
}

gsettings set $mkeys custom-keybindings "[${(j[, ])locations}]"
Improve this answer

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.