Auto Log Dictionary searches

If used as a Quick Action, neither the clipboard nor "System Events" is needed. The usage of the Quick Action would be to select some text and choose the workflow from the Services contextual menu, where it will do its thing with the selection.

For a Quick Action, the header declares what the workflow will receive. Setting this to receive text in any application will determine the context to add the workflow to the Services contextual menu - depending on the settings, it may be added to the main Services menu, but it will be available in one of those Services menus for usage with any selection. You can check the Services Settings menu item to make sure the workflow is enabled.

The "Run AppleScript" action receives the workflow item(s) in its input argument (which will always be a list), so you can get the first word from that for use with the dictionary and log. The results returned from the action will be passed to other actions in the workflow (such as "Copy to Clipboard") for further processing as desired, so the script would be something like:

on run {input, parameters}
    set theWord to first word of (input as text) -- just one word
    
    -- Log file path
    set logPath to (POSIX path of (path to desktop)) & "dictionary_log.txt"
    do shell script "touch " & quoted form of logPath
    
    -- Append the word to the log
    do shell script "echo " & quoted form of theWord & " >> " & quoted form of logPath
    
    -- Open Dictionary to that word
    do shell script "open dict://" & quoted form of theWord
    
    return input -- pass the entire selection to following actions to perform other stuff as desired
end run

As the @red_menace suggests, the nature of how this script is called is unclear. I've made the assumption that it will be called using an Automator workflow that is accessed via the script menu (ie in the User's Library > Scripts folder. Of course, adjustments can be made for different approaches.

The following should be placed inside a Run Applescript action.

use scripting additions
on run {input, parameters}
    
    tell application "System Events"
        set frontApp to name of first application process whose frontmost is true
    end tell
    set oldClipboard to the clipboard
    
    tell application frontApp
        activate
        tell application "System Events"
            tell application process frontApp
                keystroke "c" using command down
                delay 0.1
            end tell
        end tell
        set theWord to first word of (the clipboard as «class utf8»)
        delay 0.1
    end tell
    
    -- Log file path
    set logPath to (POSIX path of (path to desktop)) & "dictionary_log"
    do shell script "touch " & quoted form of logPath
    
    -- Append the word to the log
    do shell script "echo " & quoted form of theWord & " >> " & quoted form of logPath
    
    -- Open Dictionary to that word
    do shell script "open dict://" & quoted form of theWord
    
    -- Restore clipboard
    set the clipboard to oldClipboard
end run

The additions to the OP script are as follows:

• Includes use scripting additions as the clipboard is a focus here
• Gets and activates the front application so that the command-c keystroke has something to work on
• Truncates after first word so that the log file doesn't collect extraneous verbiage
• Explicitly use utf-8

I tested it on a few apps, including Firefox and Dictionary itself, without issue.