5
$\begingroup$

I have an expression $t \equiv t(x)$,

\begin{equation} t = 2^{-2+\frac{a}{2}} c^{1-\frac{a}{2}} \Gamma\left(-1+\frac{a}{2}, \frac{c}{2} x^2\right) \end{equation}

where $\Gamma\left(-1+\frac{a}{2}, \frac{c}{2} x^2\right)$ is the incomplete gamma function, and $a,c$ are constants. In general $0<a<1, 0<c<1$, but I chose specific values $a=\sqrt{20/3}, c=4/25$.

I have another expression $f \equiv f(x)$,

\begin{equation} f = x^{2+2a} e^{c\, x^2 \,/2}. \end{equation}

I would like to find a way to write $f \propto t^b$ for some power $b$. I am interested in the regime where $x \rightarrow \infty$ or at least $x \gg 1$. Since the function $\Gamma\left(-1+\frac{a}{2}, \frac{c}{2} x^2\right)$ is non-elementary, there is no trivial way to invert this to give $x \equiv x(t)$ such that $f \propto t^b$. So, I am thinking maybe there is a way to have an approximation $f \sim t^b$ and use some numerical technique to achieve this.

I have tried fitting $f(x)$ with $k t^b$ for some parameters $k,b$ in order to force the search of the relation $f(x) \sim t^b$. Although I don't think this is a good way to approximate the relation.

t[a_, c_, x_] := 2^(-2 + a/2) c^(1 - a/2) Gamma[-1 + a/2, c x^2/2]
f[a_, c_, x_] := x^(2 + 2 a) Exp[c x^2/2]
table = Table[Log[f[Sqrt[20/3], 4/25, x], 10], {x, 10, 50, 1}];
fit = FindFit[table, k t^b, {k, b}, t]
{k -> 0.1169332281, b -> -0.4908628423}

I would like to ask for some guidance or some insights on how to execute this.

Edit: To be consistent, I should have chosen $0< a <1$, say $a=1/3$. Although it is still very informative if there is a power-law solution for parameters that go outside the range of the given.

Improve this question
$\endgroup$
21
  • 2
    $\begingroup$ Not exactly what you want, but Asymptotic[(f[x]*t*c)/ (x^(-2 + 2 Sqrt[15])), x -> Infinity] is (*1*) so $f$ grows sub-exponentially with $1/t$ at least. $$f \propto \frac{x^{-2 + 2 \sqrt{15}}}{c~t}$$ for large $x$. You should probably make sure I copied down the equations correctly though. $\endgroup$ Commented Dec 27, 2024 at 14:30
  • 1
    $\begingroup$ If you allow $\log{t}$ in your approximation, we can have $$f \propto \frac{\left(-\frac{2 \log (t)}{c}\right)^{\frac{3 \ a}{2}-1}}{c~t}$$ But this is kind of cheating because $\log t$ cannot be expressed as a finite power series of $t$. same notebook here but with additional stuff $\endgroup$ Commented Dec 27, 2024 at 19:35
  • 3
    $\begingroup$ @ydd Personally, the point I took from your first comment (actually from the exponential factors in the individual asymptotics of each of f and t at infinity) is that it is impossible to get x in terms of t^b for some power b. $\endgroup$ Commented Dec 28, 2024 at 0:19
  • 1
    $\begingroup$ @mathemania From above comments by ydd it follows that there is no $b$ such that $f/t^b$ had finite nonzero limit as $x\to\infty$. What do you want then? $\endgroup$ Commented Dec 28, 2024 at 2:08
  • 1
    $\begingroup$ @UlrichNeumann. mathemania, Here is a copy of the markdown of my answer, with some extra tips thrown in about the solution method: pastebin.com/Zx2Q5sA1 -- If it works for you, let me know. If nothing else, my students would probably appreciate knowing that someone else out in the world found such stuff useful. :) $\endgroup$ Commented Dec 30, 2024 at 17:00

2 Answers 2

Reset to default
1
$\begingroup$

to long for a comment, perhaps an answer:

asymptotics of 2^(-2 + a/2) c^(1 - a/2) Gamma[-1 + a/2, c x^2/2], x->Infinity:

tasy=Asymptotic[2^(-2 + a/2) c^(1 - a/2) Gamma[-1 + a/2, c x^2/2], x->Infinity]
(*(E^(-((c x^2)/2)) x^(-4 + a))/c*)

tasy tends to zero as x->Infinity:

Limit[tasy,x->Infinity]  (*ConditionalExpression[0, a \[Element] Reals && c > 0]*)

The asymptotic equation can be solved for x( c>0):

solx=Solve[tasy==t,x]
(*{{x -> -((I Sqrt[-4 + a] Sqrt[ProductLog[-((c (c t)^(2/(-4 + a)))/(-4 +a))]])/Sqrt[c])}, 
{x -> (I Sqrt[-4 + a] Sqrt[ProductLog[-((c (c t)^(2/(-4 + a)))/(-4 + a))]])/Sqrt[c]}}*)

solx contains two solutions, which get real if a<4:

Block[{a = Sqrt[20/3] ,
  c = 4/25}, 
 zw = Table[{t, Re [Evaluate[x /. solx]]}, {t, 
    Range[0.001, 1, .001]} ] ;
 Show[{ListPlot[Map[{#[[1]], #[[2, 1]]} &, zw], PlotStyle -> Blue], 
   ListPlot[Map[{#[[1]], #[[2, 2]]} &, zw], PlotStyle -> Red]}, 
  PlotRange -> All, AxesLabel -> {t, x}]
 ]

enter image description here

The blue line shows x[t] QP asked for!

modified

power series around t=0 ( Thanks @Mariusz Iwaniuk for his helpful comment) only exists for a>4 (Contrary to the claim a<4 )

    Series[x /. solx, {t, 0, 1}, Assumptions -> {c > 0, a > 4}]
    (*

    {-I Sqrt[(-4 + a)/c]
       Sqrt[-((c^(1 + 2/(-4 + a)) t^(2/(-4 + a)))/(-4 + a)) - (
       c^(2 + 4/(-4 + a)) t^(4/(-4 + a)))/(-4 + a)^2 - (
       3 c^(3 + 6/(-4 + a)) t^(6/(-4 + a)))/(2 (-4 + a)^3)], 
     I Sqrt[(-4 + a)/c]
       Sqrt[-((c^(1 + 2/(-4 + a)) t^(2/(-4 + a)))/(-4 + a)) - (
       c^(2 + 4/(-4 + a)) t^(4/(-4 + a)))/(-4 + a)^2 - (
       3 c^(3 + 6/(-4 + a)) t^(6/(-4 + a)))/(2 (-4 + a)^3)]}

*)

addendum

Knowing ProductLog[z]~Log[z], z->Infinity we can simplify result solx asymptotically a bit more

x^2 /. solx /. ProductLog -> Log // PowerExpand
(*{-(((-4 + a) (I \[Pi] - Log[-4 + a] + Log[c] + (2 (Log[c] + Log[t]))/(-4 + a)))/c),
-(((-4 + a) (I \[Pi] - Log[-4 + a] + Log[c] + (2 (Log[c] + Log[t]))/(-4 + a)))/c)}*)

Result x^2 asymptotically depends on Log[t] (see @Roman's answer too)!

Improve this answer
$\endgroup$
7
  • $\begingroup$ Try: Series[ProductLog[-((c (c t)^(2/(-4 + a)))/(-4 + a))], {t, 0, 1}, Assumptions -> {0 < c < 1, 0 < a < 1}]. Works fine.? $\endgroup$ Commented Dec 28, 2024 at 14:08
  • $\begingroup$ @MariuszIwaniuk Thanks, I only tried without assumptions and got expressions like ProductLog[-((0^(2/(-4 + a)) c)/(-4 + a))] $\endgroup$ Commented Dec 28, 2024 at 14:12
  • $\begingroup$ @MariuszIwaniuk So, I guess there's really no way for a polynomial approximation as $x \rightarrow \infty$? $\endgroup$ Commented Dec 30, 2024 at 14:57
  • 2
    $\begingroup$ @Mathemania Yes, only the square of the asymptotic solution x is in the form of power law. $\endgroup$ Commented Dec 30, 2024 at 16:45
  • 1
    $\begingroup$ @Mathemania I corrected my answer. Real solution exists if a<4! $\endgroup$ Commented Dec 30, 2024 at 17:46
2
$\begingroup$

tl;dr – I don't think it's possible.

t[a_, c_, x_] = 2^(-2 + a/2) c^(1 - a/2) Gamma[-1 + a/2, c x^2/2];
f[a_, c_, x_] = x^(2 + 2 a) Exp[c x^2/2];

For $x\to\infty$ the value of $t$ is positive and very small:

q[x_] = Asymptotic[t[a, c, x], x -> ∞] // PowerExpand // FullSimplify
(*    (E^(-((c x^2)/2)) x^(-4 + a))/c    *)

From this asymptotic relationship we find an approximation for $x(t)$: renaming $\tau=t$ in order to avoid a symbol collision,

Solve[q[x] == τ, x] // FullSimplify
(*    {{x -> -((I Sqrt[-4 + a] Sqrt[ProductLog[-((c (c τ)^(2/(-4 + a)))/(-4 + a))]])/Sqrt[c])},
       {x -> (I Sqrt[-4 + a] Sqrt[ProductLog[-((c (c τ)^(2/(-4 + a)))/(-4 + a))]])/Sqrt[c]}}    *)

We pick the positive solution:

ξ[a_, c_, τ_] = -((I Sqrt[-4 + a] Sqrt[ProductLog[-((c (c τ)^(2/(-4 + a)))/(-4 + a))]])/Sqrt[c]);

The function $f$ now becomes

g[a_, c_, τ_] = f[a, c, ξ[a, c, τ]];

What you want is $g(\tau)\propto\tau^b$. What I find for your specific parameters $a=\sqrt{\frac{20}{3}}$, $c=\frac{4}{25}$, is

$$ g\left(\sqrt{\frac{20}{3}},\frac{4}{25},\tau\right)\approx\frac{25^{\sqrt{15}} \log ^{\sqrt{15}-1}\left(\frac{1}{\tau }\right)}{2^{\sqrt{15}+1} \tau} \text{ as $\tau\to0^+$}. $$

h[τ_] = (25^Sqrt[15] Log[1/τ]^(Sqrt[15] - 1))/(2^(Sqrt[15] + 1) τ);
With[{a = Sqrt[20/3], c = 4/25},
  Limit[g[a, c, τ] / h[τ], τ -> 0, Direction -> "FromAbove"]]
(*    1    *)

So there is an extra logarithmic dependency and a polynomial limit is not possible. Similiar, most likely, for other values of $a,c$.

Improve this answer
$\endgroup$

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.