5

I have a data file A.txt (field separator = \t) :

Well    Well Type   Well Name   Dye Target  
A1      Unknown     HIGH-001    FAM ViroFAM                 
A1      Unknown     HIGH-001    HEX ViroHEX

And a template file B.txt:

kit
Software Version = NOVA_v1
Date And Time of Export = 07/02/2020 13:44:11 UTC
Experiment Name =
Instrument Software Version =
Instrument Type = CFX
Instrument Serial Number =
Run Start Date =
Run End Date =
Run Operator =
Batch Status = VALID
Method = Novaprime
Date And Time of Export,Batch ID,Sample Name,Well,Sample Type,Status,Interpretive Result,Action*,Curve analysis
,taq,205920777.1,A01,Unkn-01
,taq,neg5,A02,Unkn-09
,,,,,,,,,,
*reporting.

And I want to print replace the value after the =in the second line of B.txt with VIRO_v1, but only when the pattern ViroHEX is present in the 5th column of A.txt.

In order to do that I start something like :

awk -F'\t' '
  FNR==NR{ a[NR]=$2; next }
  $1=="Software Version"{ print $0,"VIRO_v1"; next }
  1
' B.txt FS=" =" B.txt > result.txt

But I didn't figure it out the part with A.txt. Do you have an idea how to do that?

Improve this question

3 Answers 3

Reset to default
6 
awk -F'\t' '
  NR==FNR{ if ($5=="ViroHEX"){ viro=1 } next }
  viro && $1=="Software Version"{ $2="VIRO_v1" }
  1
' A.txt FS=" = " OFS=" = " B.txt > result.txt

This replaces the second field (NOVA_v1) with VIRO_v1 in the second file if the first field equals Software Version and ViroHEX is present anywhere in the 5th column of the first file.

I'm assuming the field separator of the second file is <space>=<space> (not a tab).

Improve this answer
0
4

Similar to berndbausch's solution, but being a bit more careful about what we're actually matching and inserting.

awk -F '\t' '$5 == "ViroHEX" { found = 1; exit } END { exit !found }' A.txt &&
sed '2 s/=.*/= VIRO_v1/' B.txt

This first uses awk to determine whether the exact string ViroHEX occurs in the fifth tab-delimited field, on any line, in the file A.txt. It does not read more of the file than what is necessary, and exits with an exit status that is later used to conditionally run sed.

The sed command replaces everything form the first = character on the second line of B.txt with the string = VIRO_v1.

If the A.txt file does not contain ViroHEX in the fifth column, no output is produced.

The following variation always produces the B.txt file, possibly with a replacement done on the second line:

if awk -F '\t' '$5 == "ViroHEX" { found = 1; exit } END { exit !found }' A.txt
then
    sed '2 s/=.*/= VIRO_v1/'
else
    cat
fi <B.txt

If you, instead of modifying line 2, want to modify the line saying Software Version = ..., then change the expression used in the calls to sed into

s/^\(Software Version = \).*/\1 VIRO_v1/
Improve this answer
4

A simpler solution, in my humble opinion. Unfortunately it uses other tools besides awk.

awk '{print $5}' A.txt | grep -q VIROHEX && sed 2s/NOVA/VIRO/ B.txt

The part before && implements the condition, the sed program replaces the text in file B.txt.

EDIT: Thanks, AdminBee, for pointing out that my solution is lazy. Better:

awk '{print $5}' A.txt | grep -q VIROHEX && sed '2s/=.*/= VIRO_v1/' B.txt
Improve this answer
0

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.