Delete records in different tables

You can't ordinarily delete from more than one table in a single T-SQL DELETE statement.

It is possible to achieve the same effect using triggers or cascading foreign keys with an ON DELETE CASCADE option, but that's probably not what you need.

If you just want to submit a single batch of text and ensure all three deletion actions either succeed or fail as a unit, use a transaction:

SET XACT_ABORT ON;

BEGIN TRY
    BEGIN TRANSACTION;

        DELETE FROM dbo.UserInfo1
        WHERE
            UserIndex = 1 
            AND ItemNumber = 5202;

        DELETE FROM dbo.UserInfo2
        WHERE
            UserIndex = 1 
            AND ItemNumber = 5202;

        DELETE FROM dbo.UserInfo3
        WHERE
            UserIndex = 1 
            AND ItemNumber = 5202;

    COMMIT TRANSACTION;
END TRY
BEGIN CATCH
    DECLARE @msg nvarchar(2048) = ERROR_MESSAGE();
    IF @@TRANCOUNT > 0 ROLLBACK TRANSACTION;
    RAISERROR (@msg, 16, 1);
    RETURN;
END CATCH;

More generally, it is a bad pattern to have such similar tables distinguished only by a suffix number. This suggests you really ought to have a single table instead with an extra column to distinguish the three sets.

A single statement DELETE would then be trivial.